Übungsaufgaben zur Tabellenkalkulation

=C4+D4

Weil ein Datum intern eine Zahl (Tage) ist, wird die Dauer einfach addiert. Beide Bezüge sind relativ, da sie beim Kopieren mit der Zeile wandern sollen. (2 Punkte; ein ausgerechnetes Datum gibt keine Punkte.)

Mit verschachteltem WENN und Typ 2 (Montag = 1 … Sonntag = 7):

=WENN(WOCHENTAG(E4;2)=6;E4+2;WENN(WOCHENTAG(E4;2)=7;E4+1;E4))

Englisch: =IF(WEEKDAY(E4;2)=6;E4+2;IF(WEEKDAY(E4;2)=7;E4+1;E4))

Gleichwertige Lösungen:

• ohne Typ (Standard: Sonntag = 1, Samstag = 7): =WENN(WOCHENTAG(E4)=7;E4+2;WENN(WOCHENTAG(E4)=1;E4+1;E4))

• kompakt: =WENN(WOCHENTAG(E4;2)>5;E4+8-WOCHENTAG(E4;2);E4)

Ergebnis z. B. für Zeile 7: 06.03.2027 ist ein Samstag (WOCHENTAG mit Typ 2 = 6) → 08.03.2027; Zeile 9: 31.01.2027 ist ein Sonntag (7) → 01.02.2027.

Bewertung: 1 Punkt Wochentagsermittlung mit passendem Typ bzw. passenden Zahlen, je 1 Punkt für Samstag (+2) und Sonntag (+1), 1 Punkt für den Sonst-Fall (E4 unverändert), 1 Punkt für korrekte Schachtelung/Syntax. Werden Samstag und Sonntag mit der Standardnummerierung verwechselt (z. B. =7 für Sonntag ohne Typ 2), höchstens 3 Punkte.

=$B$1-F4

Der Barcamp-Termin in B1 muss absolut adressiert sein ($B$1; B$1 reicht ebenfalls, weil nur nach unten kopiert wird), die Frist F4 relativ. Ergebnis 13.03.2027 − 12.02.2027 = 29 Tage. Alternativ =TAGE($B$1;F4). Die Zelle muss als Zahl formatiert sein, sonst erscheint ein Datum.

Bewertung: 1 Punkt Differenz in der richtigen Reihenfolge, 2 Punkte für den absoluten bzw. gemischten Bezug auf B1. Mit =B1-F4 (kopiert: =B2-F5 …) höchstens 1 Punkt.

Ohne Typ zählt WOCHENTAG ab Sonntag = 1 bis Samstag = 7.

• F4: E4 = 12.02.2027 ist ein Freitag → WOCHENTAG(E4) = 6 > 5 → E4 + (8 − 6) = 14.02.2027 (ein Sonntag). Ein Freitag wird fälschlich verschoben.

• F9: E9 = 31.01.2027 ist ein Sonntag → WOCHENTAG(E9) = 1, nicht > 5 → 31.01.2027 bleibt stehen. Der Sonntag wird nicht verschoben.

(Ebenso wird ein Samstag mit Wert 7 nur um einen Tag auf den Sonntag verschoben.)

Fehler: Hannah hat mit der Nummerierung „Montag = 1 … Sonntag = 7“ gerechnet, die Funktion verwendet ohne zweites Argument aber „Sonntag = 1 … Samstag = 7“. Ihre Formel behandelt deshalb Freitag und Samstag als Wochenende.

Korrektur: in beiden WOCHENTAG-Aufrufen den Typ 2 angeben:

=WENN(WOCHENTAG(E4;2)>5;E4+(8-WOCHENTAG(E4;2));E4)

Dann ergibt Samstag 6 → +2 und Sonntag 7 → +1.

Bewertung: je 1 Punkt für die beiden ermittelten Werte, 2 Punkte für die Fehlerbeschreibung (falsche Nummerierung, Folge), 1 Punkt für die Korrektur.

=ZÄHLENWENN(Anmeldungen!$D$2:$D$401;A4)

Englisch: =COUNTIF(Anmeldungen!$D$2:$D$401;A4). Der Bereich muss den Blattnamen enthalten und beim Kopieren fest bleiben; das Kriterium A4 ist relativ. Anmeldungen!D:D (ganze Spalte) ist ebenfalls richtig, ebenso $D$2:$D$361, solange keine weiteren Anmeldungen hinzukommen.

Bewertung: 1 Punkt Funktion mit Kriterium A4, 1 Punkt Blattbezug, 1 Punkt absoluter Bereich.

=AUFRUNDEN(B4*(1+$B$1);0)

Englisch: =ROUNDUP(B4*(1+$B$1);0). Beispiel: 182 · 1,05 = 191,1 → 192 Portionen.

Bewertung: 1 Punkt Rechnung mit Puffer (Klammer!), 1 Punkt absoluter Bezug auf B1, 1 Punkt Aufrunden auf 0 Nachkommastellen. Gleichwertig: =AUFRUNDEN(B4+B4*$B$1;0).

=SVERWEIS(A4;Verpflegung!$A$2:$B$6;2;FALSCH)

Englisch: =VLOOKUP(A4;Verpflegung!$A$2:$B$6;2;FALSE). Die Formel für E4 ist dann =C4*D4.

Bewertung: je 1 Punkt für Suchkriterium A4, absolute Matrix mit Blattnamen, Spaltenindex 2 und FALSCH/0 für die genaue Suche.

• Relative Matrix: Beim Kopieren verschiebt sich der Suchbereich mit: D5 sucht in Verpflegung!A3:B7, D8 nur noch in Verpflegung!A6:B10. Die oberen Einträge der Preisliste fehlen dann. Solange die Reihenfolge in Catering genau der Reihenfolge in Verpflegung entspricht, fällt das nicht auf. Wird aber z. B. das Blatt Catering nach Anmeldezahlen sortiert oder kommt ein Essenswunsch hinzu, findet die Formel ihren Eintrag nicht mehr (#NV) oder einen falschen. Korrektur: Verpflegung!$A$2:$B$6.

• Fehlender vierter Parameter: Ohne FALSCH sucht SVERWEIS ungefähr und setzt eine aufsteigend sortierte erste Spalte voraus. Die Essenswünsche sind nicht alphabetisch sortiert („keine Angabe“ vor „glutenfrei“). Die Formel kann deshalb den Preis eines anderen Eintrags liefern, und ein unbekannter oder falsch geschriebener Essenswunsch führt nicht zu #NV, sondern zu einem plausibel aussehenden falschen Preis. Korrektur: vierter Parameter FALSCH.

Bewertung: je Fehler 1 Punkt für die Benennung und 1 Punkt für die Folge.

Bewertung: E10 1 Punkt, E11 1 Punkt, E12 1 Punkt, E14 1 Punkt, E15 2 Punkte (Bezug auf das Budget, Division in der richtigen Richtung). =E10*0,03 gibt nur einen halben Punkt, weil der Rabattsatz in B11 steht; eingetragene Zahlenwerte geben keine Punkte. Folgefehler aus bb) bis bd) werden nicht erneut abgezogen.

Zwei Beispiele, je 2 Punkte (1 Punkt Einsatz, 1 Punkt konkrete Beschreibung):

• Budgetplanung und -kontrolle: Plan- und Ist-Kosten für Technik-Leihgeräte, Schriftdolmetschung, Catering und Druck gegenüberstellen; die Tabelle zeigt sofort, wie viel vom Budget (6.000 €) noch frei ist.

• Schichtplan der Helfenden: Zuordnung der rund 40 Helfenden zu Schichten und Aufgabenbereichen, mit ZÄHLENWENN-Kontrolle, ob jede Schicht mindestens zwei Personen hat.

• Simulation: „Was kostet das Catering bei 300, 350 oder 400 Teilnehmenden?“ – ein Eingabewert ändern, alle Kosten werden neu berechnet.

• Auswertung des Feedbacks: Export der Feedbackbögen einlesen, Durchschnittsnoten je Session berechnen und als Diagramm darstellen.

• Strombedarf je Stand oder je Raum aus den Geräteleistungen berechnen.

• Arbeitszeiterfassung der Lehrkräfte für den Samstagseinsatz.

Zwei Probleme, je 2 Punkte (Problem und Auswirkung):

• Unterschiedliche Versionen: Jede Person bearbeitet ihre eigene Kopie. Änderungen müssen von Hand zusammengeführt werden; es ist unklar, welche Datei aktuell ist, und Einträge gehen verloren.

• Kein gleichzeitiges Arbeiten / Sperren: Eine lokal geöffnete Datei kann nur eine Person bearbeiten; andere warten oder arbeiten mit veralteten Daten.

• Schlechte Wartbarkeit: Mit wachsender Zahl von Blättern und Abhängigkeiten zwischen den Formeln (Anmeldungen → Catering → Budget) ist schwer nachzuvollziehen, welche Zelle wovon abhängt; eine Änderung kann unbemerkt andere Berechnungen zerstören.

• Fehleranfälligkeit: Formeln werden versehentlich mit Zahlen überschrieben oder falsch kopiert; es gibt keine Pflichtfelder oder Datentypprüfungen.

• Datenschutz und Rechte: Die Datei enthält personenbezogene Daten (Namen, Essenswünsche, Barrierefreiheitsbedarf). Per E-Mail verschickt, kann jede*r alles sehen und weiterleiten; es gibt keine abgestuften Rechte.

• Keine Nachvollziehbarkeit: Wer wann welchen Wert geändert hat, lässt sich ohne Versionsverlauf nicht feststellen.

Je Fehler 1 Punkt:

• Angebot 2: Das Datum 09/08/2026 steht im US-Format (Monat/Tag/Jahr mit Schrägstrichen). Es wird nicht als deutsches Datum erkannt oder als 09.08.2026 (August) statt 08.09.2026 gelesen.

• Angebot 3: Die Zeile verwendet das Komma statt des Semikolons als Trennzeichen und den Dezimalpunkt in 1.70. Die ganze Zeile landet in der ersten Spalte (bzw. der Betrag wird als Text oder Datum erkannt).

• Angebot 4: In der Zahlenspalte plaetze steht der Text drei statt der Zahl 3; mit dem Wert kann nicht gerechnet werden.

• Angebot 5: Am Zeilenende steht ein zusätzliches Semikolon. Die Zeile hat dadurch ein Feld mehr als die Kopfzeile (leere achte Spalte).

=SVERWEIS(C4;Haltepunkte!$A$2:$D$7;4;FALSCH)

Englisch: =VLOOKUP(C4;Haltepunkte!$A$2:$D$7;4;FALSE). Der Spaltenindex ist 4, weil die Entfernung in der vierten Spalte der Matrix A:D steht. (Hier wäre auch die ungefähre Suche zufällig richtig, weil die Nummern aufsteigend sortiert sind – eine unbekannte Nummer 7 würde dann aber die Entfernung von Haltepunkt 6 liefern.)

Bewertung: je 1 Punkt für Suchkriterium, absolute Matrix mit Blattnamen, Spaltenindex 4, genaue Suche.

=D4*$B$1

(oder =D4*B$1). Bewertung: 1 Punkt Rechnung, 1 Punkt fester Bezug auf B1. =D4*0,1 gibt 1 Punkt, weil der Höchstbetrag eine Eingabezelle hat.

• F5 enthält =D5*B2. B2 ist leer und zählt als 0 → 0,00.

• G5 vergleicht 2,50 > 0 → „zu hoch“ (hier zufällig richtig – aber jedes Angebot mit einem Beitrag über 0 € würde als zu hoch markiert).

• F6 enthält =D6*B3. In B3 steht der Text „Fahrer*in“ → Fehlerwert #WERT! (englisch #VALUE!), der auch in G6 erscheint.

Erläuterung: Beim Kopieren nach unten erhöht die Tabellenkalkulation die Zeilennummer aller relativen Bezüge. Entscheidend ist also, dass die Zeile 1 fest bleibt. $B$1 fixiert Spalte und Zeile, B$1 fixiert nur die Zeile – beides bleibt beim Kopieren nach unten auf B1. $B1 fixiert nur die Spalte; die Zeile wandert weiter zu $B2, $B3 …, der Fehler bliebe bestehen.

Bewertung: 2 Punkte für die ermittelten Ergebnisse (F5/G5 und F6), 2 Punkte für die Erläuterung.

=WENN(E4>F4;"zu hoch";"ok")

Ergebnisse Zeile 4 bis 8: ok (1,80 ≤ 1,86), zu hoch (2,50 > 1,94), ok (1,70 ≤ 1,79), ok (1,50 ≤ 1,52), ok (0,00 ≤ 1,86).

Bewertung: 1 Punkt Bedingung (>; ein Beitrag genau auf dem Höchstbetrag ist zulässig), 1 Punkt Texte in Anführungszeichen, 1 Punkt Syntax.

=IF(E4>F4,"zu hoch","ok")

In englischen Programmversionen ist das Komma das Trennzeichen zwischen den Argumenten (und der Punkt das Dezimaltrennzeichen), in deutschen das Semikolon. Die Texte bleiben unverändert, weil sie Inhalte sind. (=IF(E4>F4;"zu hoch";"ok") mit Semikolon wird ebenfalls als richtig gewertet.)

Bewertung: 1 Punkt Funktionsname IF, 1 Punkt Trennzeichen.

Die PWA hat den höheren Nutzwert (4,35 gegenüber 3,85).

Bewertung: 3 Punkte für die vollständigen Spalten D und F (je Spalte 1,5 Punkte), 1 Punkt für die Entscheidung (Folgefehler werden berücksichtigt).

=$B4*C4

Beim Kopieren nach unten wandern beide Zeilennummern mit ($B5*C5 …). Beim Kopieren nach F4 (zwei Spalten weiter) bleibt die Gewichtung in Spalte B ($B), der Punktebezug rutscht von C nach E: =$B4*E4. Mit $B$4 wäre das Kopieren nach unten falsch, mit B4 würde aus der Gewichtung in F4 der Bezug D4.

Bewertung: 1 Punkt Rechnung, 2 Punkte für den gemischten Bezug $B4.

Die Summen der ungewichteten Punkte in C9 (21) und E9 (20) sind nicht sinnvoll: Sie behandeln alle Kriterien gleich wichtig und widersprechen damit der vereinbarten Gewichtung. Sie tragen zur Entscheidung nichts bei und können zu einer falschen Entscheidung verleiten (hier zeigen sie zufällig in dieselbe Richtung). Entscheidend sind nur D9 und F9.

Nützlich ist dagegen die Summe der Gewichtungen in B9: Sie dient als Kontrolle, dass die Gewichte zusammen 100 % ergeben.

Bewertung: 2 Punkte für die nicht sinnvolle Berechnung mit Begründung, 1 Punkt für die Kontrollsumme B9.

Zwei Vorteile, je 2 Punkte (1 Punkt Vorteil, 1 Punkt Beschreibung mit Bezug):

• Mehrbenutzerzugriff: Viele Nutzende (Fahrer*innen und Mitfahrende) lesen und schreiben gleichzeitig. Transaktionen und Sperren verhindern, dass zwei Personen den letzten freien Platz buchen.

• Rechteverwaltung und Datenschutz: Benutzer und Rollen mit abgestuften Rechten; Mitfahrende sehen z. B. über eine View nur die Daten, die sie für ihre Fahrt brauchen, die Administration dagegen alle.

• Datenintegrität: Datentypen, Pflichtfelder, Fremdschlüssel und CHECK-Bedingungen verhindern Einträge wie „drei“ statt 3, ein US-Datum oder ein Angebot zu einem nicht vorhandenen Haltepunkt.

• Keine Redundanz: Haltepunkte und Personen werden einmal gespeichert und nur referenziert (Normalisierung) statt in jeder Zeile wiederholt.

• Anbindung an die App: Web-App und REST-API greifen per SQL direkt auf den aktuellen Datenbestand zu; kein Export und Import von Dateien.

• Leistung und Datensicherung: auch bei vielen Datensätzen schnelle Abfragen über Indizes; regelmäßige, automatisierte Backups.